function wrtts(arg)
*
* writes out a time series of fields for convertion to grib2
* usage run wrtts.gs variablename file inv
*
* v1.0 w. ebisuzaki

var=subwrd(arg,1)
file=subwrd(arg,2)
fileinv=file '.inv'
inv=subwrd(arg,3)


* Get the inv  which may contain more than one word
* If no title is specified, it will be the variable expression
inv = ''
inv=subwrd(arg,3)
i = 4
while (subwrd(arg,i) != '')
   inv = inv%' '%subwrd(arg,i)
   i = i+1
endwhile
say 'inv=' inv
if (inv = '')
   say 'usage: grads-variable output-file inventory'
   exit
endif

* save gxout
'q gxinfo'
line=sublin(result,1)
gxout=subwrd(line,4)
if (gxout = 'Clear')
  gxout='shaded'
endif
if (gxout = 'Line')
  gxout='contour'
endif



'query dim'
diminfo = result
line5 = sublin(diminfo,5)
type = subwrd(line5,3)
if (type = 'fixed')
   date1 = subwrd(line5,6)
   date2 = date1
   time1 = subwrd(line5,9)
   time2 = time1
else
   time1 = subwrd(line5,11)
   time2 = subwrd(line5,13)
   date1 = subwrd(line5,6)
   date2 = subwrd(line5,8)
endif

i=time1

say 'date from ' date1 ' to ' date2

* write data file
'q fwrite'
info=result
line=sublin(info,1)
open=subwrd(line,4)
if (open != 'open')
   'set fwrite -le ' file
    say 'opening fwrite file'
endif
'set gxout fwrite'

while (i <= time2)
   'set t ' i
   say 'd ' var
   'd ' var
   'query dim'
   diminfo = result
   line5 = sublin(diminfo,5)
   date = subwrd(line5,6)
   hr = substr(date,1,2)
   day = substr(date,4,2)
   mon = substr(date,6,3)
   year = substr(date,9,4)
   if (mon = 'JAN') ; mo = 01; endif
   if (mon = 'FEB') ; mo = 02; endif
   if (mon = 'MAR') ; mo = 03; endif
   if (mon = 'APR') ; mo = 04; endif
   if (mon = 'MAY') ; mo = 05; endif
   if (mon = 'JUN') ; mo = 06; endif
   if (mon = 'JUL') ; mo = 07; endif
   if (mon = 'AUG') ; mo = 08; endif
   if (mon = 'SEP') ; mo = 09; endif
   if (mon = 'OCT') ; mo = 10; endif
   if (mon = 'NOV') ; mo = 11; endif
   if (mon = 'DEC') ; mo = 12; endif

   r='1:0:d='year mo day hr ':' inv ':'
   say r
   err=write(fileinv, r,append)
   i = i + 1
endwhile
'set t ' time1 ' ' time2

* 'disable fwrite'
'set gxout ' gxout
say 'set gxout ' gxout