#! /bin/csh -f

################################################################################
# SCRIPT
#   xm.download_CMORPH_data_1mo
#
# LANGUAGE
#   C-Shell Script
#
#-------------------------------------------------------------------------------
# PURPOSE
#   This script is used to download 8km-30min CMORPH CDR data files from NCEI
#   data server for target month
#
# USAGE
#   xm.download_CMORPH_data_1mo <yyyymm>
#
#-------------------------------------------------------------------------------
# COMMAND-LINE VARIABLES
#   yyyymm : target month
#
#-------------------------------------------------------------------------------
# SUBTOUTINES USED
#   xd.download_CMORPH_data_1dy : to download CMORPH data files for one day
#
################################################################################

#------------------------------------------------------------
# <xd> : subroutine to download CMORPH data files for one day
#------------------------------------------------------------
set xd=xd.download_CMORPH_data_1dy

#------------------------
# <yyyymm> : target month
#------------------------
if( $#argv < 1 ) then
  echo
  echo "###############################"
  echo "#                             #"
  echo "#  parameter <yyyymm> needed  #"
  echo "#                             #"
  echo "###############################"
  echo
  exit
endif
set yyyymm=${1}
set yyyy=`echo ${yyyymm} | cut -c1-4`
set mm=`echo ${yyyymm} | cut -c5-6`

#-----------------------------------------
# <ymd_n> : first day of next month
# <dmax>  : number of days in target month
#-----------------------------------------
set ymd_n=`date -u "+%Y%m%d" --date="${yyyymm}01 +1 month"`
set dmax=`date -u "+%d" --date="${ymd_n} -1 day"`

#--------------------------------------------------------
# download CMORPH data files for each day in target month
#--------------------------------------------------------
set dd=1
while( ${dd} <= ${dmax} )
  set ymd=`date -u "+%Y%m%d" --date="${yyyy}-${mm}-${dd}"`
  ./${xd} ${ymd}
  @ dd ++
end

exit