function plot_YMC(args)

*---------------------
* get target date/hour
*---------------------
yyyymmddhh=subwrd(args,1)

yyyy=substr(yyyymmddhh,1,4)
mm=substr(yyyymmddhh,5,2)
dd=substr(yyyymmddhh,7,2)
hh=substr(yyyymmddhh,9,2)

*----------
* set <MMM>
*----------
if( mm='01' )
  MMM=Jan
endif
if( mm='02' )
  MMM=Feb
endif
if( mm='03' )
  MMM=Mar
endif
if( mm='04' )
  MMM=Apr
endif
if( mm='05' )
  MMM=May
endif
if( mm='06' )
  MMM=Jun
endif
if( mm='07' )
  MMM=Jul
endif
if( mm='08' )
  MMM=Aug
endif
if( mm='09' )
  MMM=Sep
endif
if( mm='10' )
  MMM=Oct
endif
if( mm='11' )
  MMM=Nov
endif
if( mm='12' )
  MMM=Dec
endif

*------------------
* open control file
*------------------
'reinit'
'open CMORPH_V0.x_RT_8km-30min.YMC.ctl'
'set vpage 0.0 11.0 0.0 8.5'
'set gxout shaded'

*------------------
* set color palette
*------------------
'set rgb 30 150 150 150'
'set rgb 31 250 250 250'
'set rgb 32   0 225 255'
'set rgb 33   0 165 185'
'set rgb 34   0 185   0'
'set rgb 35   0 255  45'
'set rgb 36 255 255   0'
'set rgb 37 225 205   0'
'set rgb 38 160 120   0'
'set rgb 39 160  40   0'
'set rgb 40 185   0   0'
'set rgb 41 255   0 155'
'set rgb 42 185   0 255'
'set rgb 43 125   0 205'
'set rgb 44  75   0 160'

*----------------------
* plot two 30min images
*----------------------
n=0
while( n<=30 )

  if( n<10 )
    nn='0'n
  else
    nn=n
  endif

  'set time ' hh ':' nn 'z' dd MMM yyyy

  'clear'
  'set lat -15 15'
  'set lon 80 160'
  'set parea 0.5 10.5 0.8 7.7'
  'set grads off'
  'set mpdset hires'
  'set ylint 5'
  'set xlint 10'
  'set clevs 0  0.5 1  2  4  6  8  10 15 20 25 30 40'
  'set ccols 30 32  33 34 35 36 37 38 39 40 41 42 43 44'
  'd cmorph'
  'run cbar.gs'

  'set strsiz 0.25'
  'set string 1 l 11'
  'draw string 0.6 7.1 CMORPH Rainrate (mm/hr)'

  'set strsiz 0.2'
  'set string 2 r 11'
  'draw string 10.4 7.05 ' yyyy '-' MMM '-' dd ' ' hh ':' nn 'Z'

  'printim YMC_30min_' yyyy mm dd hh nn '.gif white x1100 y850'

  n=n+30

endwhile

*------------------
* plot hourly image
*------------------
'clear'
'set lat -15 15'
'set lon 80 160'
'set parea 0.5 10.5 0.8 7.7'
'set grads off'
'set mpdset hires'
'set ylint 5'
'set xlint 10'
'set clevs 0  0.5 1  2  4  6  8  10 15 20 25 30 40'
'set ccols 30 32  33 34 35 36 37 38 39 40 41 42 43 44'
*----------------------------------------------------------------
* NOTE
* hourly CMORPH rainrate is average of two 30min CMORPH rainrates
*----------------------------------------------------------------
'd ave(cmorph,time=' hh ':00z' dd MMM yyyy ',time=' hh ':30z' dd MMM yyyy ')'
'run cbar.gs'

'set strsiz 0.25'
'set string 1 l 11'
'draw string 0.6 7.1 CMORPH Rainrate (mm/hr)'

'set strsiz 0.2'
'set string 2 r 11'
'draw string 10.4 7.05 ' yyyy '-' MMM '-' dd ' ' hh 'Z'

'printim YMC_hourly_' yyyy mm dd hh '.gif white x1100 y850'

'quit'