*------------------
* open control file
*------------------
'reinit'
'open CMORPH_V0.x_RT_8km-30min.ctl'
'set vpage 0.0 11.0 0.0 8.5'
'set gxout grfill'

*------------------
* set color palette
*------------------
'set rgb 30 150 150 150'
'set rgb 31 250 250 250'
'set rgb 32   0 225 255'
'set rgb 33   0 165 185'
'set rgb 34   0 185   0'
'set rgb 35   0 255  45'
'set rgb 36 255 255   0'
'set rgb 37 225 205   0'
'set rgb 38 160 120   0'
'set rgb 39 160  40   0'
'set rgb 40 185   0   0'
'set rgb 41 255   0 155'
'set rgb 42 185   0 255'
'set rgb 43 125   0 205'
'set rgb 44  75   0 160'

*------------------
* get starting time
*------------------
say 'input <yyyymmddhhnn>'
pull cin
yyyy=substr(cin,1,4)
mm=substr(cin,5,2)
dd=substr(cin,7,2)
hh=substr(cin,9,2)
nn=substr(cin,11,2)

*-------------------
* remove leading '0'
*-------------------
if( dd<10 )
  dd=substr(dd,2,1)
endif
if( hh<10 )
  hh=substr(hh,2,1)
endif
if( nn<10 )
  nn=substr(nn,2,1)
endif

*----------------
* adjust for <nn>
*----------------
if( nn!=0 & nn!=30 )
  nn=0
endif

say

*------------------
* repeat until quit
*------------------
plot=1
while( plot=1 )

*---------------------
* set <mon> and <dmax>
*---------------------
  if( mm=1 )
    mon=Jan
    dmax=31
  endif
  if( mm=2 )
    mon=Feb
    dmax=28
    if( yyyy=2016 | yyyy=2020 )
      dmax=29
    endif
  endif
  if( mm=3 )
    mon=Mar
    dmax=31
  endif
  if( mm=4 )
    mon=Apr
    dmax=30
  endif
  if( mm=5 )
    mon=May
    dmax=31
  endif
  if( mm=6 )
    mon=Jun
    dmax=30
  endif
  if( mm=7 )
    mon=Jul
    dmax=31
  endif
  if( mm=8 )
    mon=Aug
    dmax=31
  endif
  if( mm=9 )
    mon=Sep
    dmax=30
  endif
  if( mm=10 )
    mon=Oct
    dmax=31
  endif
  if( mm=11 )
    mon=Nov
    dmax=30
  endif
  if( mm=12 )
    mon=Dec
    dmax=31
  endif

*----------------
* adjust for <dd>
*----------------
  if( dd=0 )
    dd=dmax
  endif

*----------------
* add leading '0'
*----------------
  if( dd<10 )
    dd='0'dd
  endif
  if( hh<10 )
    hh='0'hh
  endif
  if( nn<10 )
    nn='0'nn
  endif

*---------
* set time
*---------
  'set time ' hh ':' nn 'z' dd mon yyyy

  say '==> ' yyyy '-' mon '-' dd ' ' hh ':' nn 'Z'

*-----------------
* plot precip rate
*-----------------
  'clear'
  'set lat -60 60'
  'set lon 0 360'
  'set parea 0.5 10.5 0.8 7.7'
  'set grads off'
  'set grid off'
  'set ylint 10'
  'set clevs 0  0.5 1  2  4  6  8  10 15 20 25 30 40'  
  'set ccols 30 32  33 34 35 36 37 38 39 40 41 42 43 44' 
  'd cmorph'
  'run cbar.gs'

  'set string 1 l 11'
  'set strsiz 0.2'
  'draw string 0.6 6.9 CMORPH Precip Rate (mm/hr)'
  'set string 2 r 11'
  'set strsiz 0.2'
  'draw string 10.4 6.85 ' yyyy '-' mon '-' dd ' ' hh ':' nn 'Z'

*-----------------
* which way to go?
*-----------------
  say 'Quit(q) | Previous(p) | Next(n)'
  pull cin

*------------------------
* adjust time accordingly
*------------------------
  if( cin!=q & cin!=Q )
    if( cin!=p & cin!=P )
      nn=nn+30
      hh=hh+0
      dd=dd+0
      if( nn=60 )
        nn=0
        hh=hh+1
        if( hh=24 )
          hh=0
          dd=dd+1
          if( dd>dmax )
            dd=1
            mm=mm+1
            if( mm=13 )
              mm=1
              yyyy=yyyy+1
            endif
          endif
        endif
      endif
    else
      nn=nn-30
      hh=hh-0
      dd=dd-0
      if( nn<0 )
        nn=30
        hh=hh-1
        if( hh<0 )
          hh=23
          dd=dd-1
          if( dd=0 )
            mm=mm-1
            if( mm=0 )
              mm=12
              yyyy=yyyy-1
            endif
          endif
        endif
      endif
    endif
    'clear'
  else
    plot=0
  endif

endwhile