'reinit'
'open m2.CBO_V1_1deg-MON.lnx.ctl'

'set vpage 0.0 8.5 0.0 11.0'
'set gxout shaded'
'set grads off'
'set grid off'
'set lon -30 330'
'set lat -90 90'
'set z 1'

'set rgb 30 150 150 150'
'set rgb 31  60  60  60'
'set rgb 32   0 225 255'
'set rgb 33   0 165 185'
'set rgb 34   0 185   0'
'set rgb 35   0 255  45'
'set rgb 36 255 255   0'
'set rgb 37 225 205   0'
'set rgb 38 160 120   0'
'set rgb 39 160  40   0'
'set rgb 40 185   0   0'
'set rgb 41 255   0 155'
'set rgb 42 185   0 255'
'set rgb 43 125   0 205'
'set rgb 44  75   0 160'

say 'starting date <yyyymm> (default=199101):'
pull cin
if( cin='' )
  yyyy=1991
  m=1
else
  yyyy=substr(cin,1,4)
  m=substr(cin,5,2)
endif
m=m+0

if( m=1  ); mon=Jan; endif
if( m=2  ); mon=Feb; endif
if( m=3  ); mon=Mar; endif
if( m=4  ); mon=Apr; endif
if( m=5  ); mon=May; endif
if( m=6  ); mon=Jun; endif
if( m=7  ); mon=Jul; endif
if( m=8  ); mon=Aug; endif
if( m=9  ); mon=Sep; endif
if( m=10 ); mon=Oct; endif
if( m=11 ); mon=Nov; endif
if( m=12 ); mon=Dec; endif

'set time ' mon yyyy

'q dim'
line5=sublin(result,5)
tt=subwrd(line5,9)

plot=1
while( plot=1 )

  'set t ' tt

  'q time'
  hdmy=subwrd(result,3)
  my=substr(hdmy,6,7)

  say 'displaying ' my
  say

  'clear'
  'set grads off'
  'set grid off'
  'set xlint 30'
  'set ylint 30'

  'set string 1 bc 9'
  'set strsiz 0.17'
  'draw string 4.3 10.7 CPC Blended OLR (CBO) V1 [W/m^2]'

  'set string 1 bl 7'
  'set strsiz 0.15'
  'draw string 0.8 10.3 OLR'
  'draw string 0.8 5.1 Anomaly'

  'set string 2 br 7'
  'set strsiz 0.15'
  'draw string 7.8 10.3 1deg-Monthly ' my

*** Total ***
  'set parea 0.3 8.3 5.95 10.15'
  'set ccols  90   4  11   5  13   3  10   7  12   8   2 6'
  'set clevs 120 140 160 180 200 220 240 260 280 300 320'
  'd olr'
  'run /cpc/prod/cpcsat/gs/cbarn_xy.gs 1.3 7.3 5.5 5.62'

*** Anomaly ***
  'set parea 0.3 8.3 0.75 4.95'
  'set ccols   4  11   5  13  3 30  7 12  8  2 6'
  'set clevs -40 -30 -20 -10 -5  5 10 20 30 40'
  'd anom'
  'run /cpc/prod/cpcsat/gs/cbarn_xy.gs 1.3 7.3 0.3 0.42'

  say 'Quit(q) | Previous(p) | Next(any)'
  pull cin

  if( cin!=Q & cin!=q )
    if( cin!=P & cin!=p )
      tt=tt+1
    else
      tt=tt-1
    endif
  else
    plot=0
  endif

endwhile